This is for the latest WakePup:
; CONFIG.SYS for WakePup v1.1c, (C) 26-Nov-05, Paul Akterstam.
; Menu structure from FreeDOS Beta 9 distro,
http://www.fdos.org/
; v1.1c - removed USBASPI.SYS switch /w
;
!switches=/E
menucolor=7,0
menu ����������������������������������
menu WakePup v1.1c Boot Menu (26-Nov-2005)
menu ����������������������������������
menu
menu Boot Puppy from:
menu
menu 1. IDE/USB drives (built-in or external CD-ROM, HD and flash)
menu
menu 2. Iomega ZIP disk drive, connected to parallel port
menu
menu 3. Backpack CD-ROM drive, connected to parallel port
menu
menu 4. Addonics (or similar) CD-ROM drive, connected to PCMCIA
menu
menu ����������������������������������
menudefault=1,30
; load VIDE v2.14 IDE/ATAPI CD-ROM device driver
1?!device=A:\driver\VIDE-CDD.SYS /d:IDE-CD
; enable USB mass storage devices (NEC OHCI/EHCI & Intel UHCI USB controllers)
; load Panasonic v2.20 ASPI manager for USB mass storage
; (maps USB mass storage devices to ASPI devices)
1?!device=A:\driver\usb\USBASPI.SYS /v
; load Panasonic v1.00 USB CD-ROM device driver
1?!device=A:\driver\usb\USBCD.SYS /d:USB-CD
; load NOVAC v2.00 ASPI disk driver
; DI1000DD.SYS hangs with USB flash, use ASPIDISK.SYS instead
;1?!device=A:\driver\DI1000DD.SYS
; load Adaptec v4.01b ASPI disk driver
; (maps ASPI mass storage devices to DOS drive letters)
1?!device=A:\driver\ASPIDISK.SYS
; load Micro Solutions v 4.02 BACKPACK CD-ROM device driver
3?!device=A:\driver\backpack\BPCDDRV.SYS /d:BP-CD
; load Shining v5.81 PMIDE-ASC, M17 Card Services Client
; Note: If using a VIA PCMCIA controller, add parameter "/V1" to next line
4?!device=A:\driver\pcmcia\PCMI80CL.SYS /QA
; load Shining v2.70 ATAPI/IDE CD-ROM device driver
4?!device=A:\driver\pcmcia\STATPCDM.SYS /Q0 /D:PCM-CD
1234?!SHELL=A:\COMMAND.COM A:\ /E:1024 /F /MSG /P=A:\AUTOEXEC.BAT
!files=20
!buffers=20
!lastdrive=Z
-------------------------------------------
@echo off
rem WakePup v1.1c, (C) 26-Nov-05, Paul Akterstam ('pakt' on Puppy Forum)
rem Inspired by Barry Kauler's BOOT2PUP (
www.goosee.com/puppy)
rem
rem Requires FreeDOS & FreeCOM (%config% can have a value in range 0..9)
rem Uses SHSUCDX.COM, a freeware replacement for MSCDEX.EXE
rem Uses LINLD.COM with parameter file instead of TINY.EXE
rem This program is distributed in the hope that it will be useful, but
rem WITHOUT ANY WARRANTY; without even the implied warranty of
rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
rem Sections
rem (1) IDE/USB drives (built-in or external CD-ROM, HD and flash)
rem (2) Iomega ZIP drive, connected to parallel port
rem (3) Backpack CD-ROM drive, connected to parallel port
rem (4) Addonics (or similar) CD-ROM drive, connected to PCMCIA
echo.
if not "%config%"=="1" goto init
rem Pause here so USB driver messages can be read...
echo Pause for driver messages. Press any key to continue or Ctrl-C to abort...
pause >NUL
:init
cls
set pupdrv=
set cfg=
if "%config%"=="1" goto ideusb_drv
if "%config%"=="2" goto parzip_drv
if "%config%"=="3" goto parcd_drv
if "%config%"=="4" goto pcmcia_drv
goto end
:ideusb_drv
rem Section(1)
rem SHSUCDX assigns IDE CD-ROM to drive I:, USB CD-ROM to drive J:
driver\SHSUCDX /d:?IDE-CD,I /d:?USB-CD,J >NUL
echo Checking any IDE drive for marker file PUPXIDE...
for %%x in ( C D E F G H ) do if exist %%x:\pupxide set pupdrv=%%x:
if "%pupdrv%"=="" goto try_usb
set drvtype=IDE
goto ide_cd_common
:try_usb
echo.
echo Checking any USB drive for marker file PUPXUSB...
for %%x in ( C D E F G H ) do if exist %%x:\pupxusb set pupdrv=%%x:
if "%pupdrv%"=="" goto cd_drv
set drvtype=USB
goto usb_common
:parzip_drv
rem Section(2)
echo Looking for an Iomega parallel port ZIP drive...
driver\zipdrv\GUEST letter=I
echo Looking for marker file PUPXIDE...
if exist I:\pupxide set pupdrv=I:
if "%pupdrv%"=="" goto failed
set drvtype=ZIP
goto ide_cd_common
:parcd_drv
rem Section(3)
echo Looking for a Backpack parallel port CD-ROM drive...
rem SHSUCDX assigns parallel port CD-ROM to drive I:
driver\SHSUCDX /d:?BP-CD,I >NUL
goto cd_drv
:pcmcia_drv
rem Section(4)
rem Looking for an Addonics (or similar) PCMCIA CD-ROM drive...
rem SHSUCDX assigns PCMCIA CD-ROM to drive I:
driver\SHSUCDX /d:?PCM-CD,I >NUL
goto cd_drv
:cd_drv
echo.
echo Checking any CD-ROM drive for file IMAGE.GZ...
for %%x in ( I J ) do if exist %%x:\image.gz set pupdrv=%%x:
if "%pupdrv%"=="" goto failed
set drvtype=CD-ROM
:ide_cd_common
echo ...file found on %drvtype% drive %pupdrv%
echo.
echo ����������������������������������
echo Select drive boot options
echo ����������������������������������
echo
echo 1. PFILE=pup001-none-262144 (Default)
echo
echo 2. acpi=off PFILE=pup001-none-262144
echo
echo 3. PFILE=ask (choose pupxxx name & location)
echo
echo 4. acpi=off PFILE=ask (choose pupxxx name & location)
echo
echo ����������������������������������
echo.
choice /C:1234 Enter a choice :
if "%errorlevel%"=="1" set cfg=IDECD1.CFG
if "%errorlevel%"=="2" set cfg=IDECD2.CFG
if "%errorlevel%"=="3" set cfg=IDECD3.CFG
if "%errorlevel%"=="4" set cfg=IDECD4.CFG
goto boot_drv
:usb_common
echo ...file found on USB drive %pupdrv%
echo.
echo ����������������������������������
echo Select USB drive boot options
echo ����������������������������������
echo
echo 1. PSLEEP=25 PHOME=sda1 PFILE=pup100-none-262144 (Default)
echo
echo 2. acpi=off PSLEEP=25 PHOME=sda1 PFILE=pup100-none-262144
echo
echo 3. PSLEEP=25 PFILE=ask (choose pupxxx name & location)
echo
echo 4. acpi=off PSLEEP=25 PFILE=ask (choose pupxxx name & location)
echo
echo ����������������������������������
echo.
choice /C:1234 Enter a choice :
if "%errorlevel%"=="1" set cfg=USB1.CFG
if "%errorlevel%"=="2" set cfg=USB2.CFG
if "%errorlevel%"=="3" set cfg=USB3.CFG
if "%errorlevel%"=="4" set cfg=USB4.CFG
:boot_drv
echo.
LINLD.COM image=%pupdrv%\vmlinuz initrd=%pupdrv%\image.gz cl=@%cfg%
goto end
:failed
echo.
type FAILMSG.TXT
:end